110 midterm 1 题库加精选

javaIsTheBest

========================step question============================
============================Q1===================================
(define RATE 3)
(define LIMIT 20)
(define (foo a b)
  (if (or (<= (+ a RATE) LIMIT)
          (> (* b 2) LIMIT))
      (+ a RATE)
      LIMIT))

;; Show the step by step evaluation of the following expression:

(foo (+ 10 3) (* 2 3))

solution:
(foo 13 (* 2 3))

(foo 13 6)

(if (or (<= (+ 13 RATE) LIMIT)
        (> (* 6 2) LIMIT))
    (+ 13 RATE)
    LIMIT)

(if (or (<= (+ 13 3) LIMIT)
        (> (* 6 2) LIMIT))
    (+ 13 RATE)
    LIMIT)

(if (or (<= 16 LIMIT)
        (> (* 6 2) LIMIT))
    (+ 13 RATE)
    LIMIT)

(if (or (<= 16 20)
        (> (* 6 2) LIMIT))
    (+ 13 RATE)
    LIMIT)

(if (or true
        (> (* 6 2) LIMIT))
    (+ 13 RATE)
    LIMIT)
    

(if true
    (+ 13 RATE)
    LIMIT)

(+ 13 RATE)

(+ 13 3)

16
=================================================================
==============================Q2=================================
(define F1 false)
(define F2 true)
(define F3 false)

(define (foo a b)
  (and a b))

;; Show the step by step evaluation of the following expression:

(foo F1 (or F2 F3))

solution:
;(foo F1 (or F2 F3))
;(foo false (or F2 F3))
;(foo false (or true F3))
;(foo false true)
;(and false true)
;false
=================================================================
==============================Q3=================================
(define BAR 12)

(define (foo x y)
  (if (and (> y x)
           (> (+ BAR x) (* 2 y)))
      (- y x)
      (+ x y)))


Write out the step by step evaluation of:
   (foo (+ 1 4) (+ 1 2))

solution:
(foo (+ 1 4) (+ 1 2))

(foo 5 (+ 1 2))

(foo 5 3)

(if (and (> 3 5)
         (> (+ BAR 5) (* 2 3)))
    (- 3 5)
    (+ 5 3))

(if (and false
         (> (+ BAR 5) (* 2 3)))
    (- 3 5)
    (+ 5 3))

(if false
    (- 3 5)
    (+ 5 3))

(+ 5 3)

8
=================================================================
==============================Q4=================================
Given

(define y 4)

(define (foo x)
  (if (< (* 2 x) y)
      (+ x y)
      x))

Write out the step-by-step evaluation of:
  (foo (* 2 3))

Include the original expression and the final result.

solution:
(define y 4)

(define (foo x)
  (if (< (* 2 x) y)
      (+ x y)
      x))

(foo (* 2 3))

(foo 6)

(if (< (* 2 6) y)
    (+ 6 y)
    6)

(if (< 12 y)
    (+ 6 y)
    6)

(if (< 12 4)
    (+ 6 y)
    6)

(if false
    (+ 6 y)
    6)

6
=================================================================

javaIsTheBest

========================htdf question============================
============================Q1===================================
Design a function that consumes a string and a number, and produces true if 
the string is longer than the given number.

solution:
(@htdf longer-than-n?)
(@signature String Natural -> Boolean)
;; produce true if string is longer than given number
(check-expect (longer-than-n? "hi" 3) false)
(check-expect (longer-than-n? "hi" 2) false)
(check-expect (longer-than-n? "hi" 1) true)
(check-expect (longer-than-n? "hello" 3) true)

;(define (longer-than-n? s n) false)

(@template String add-para)

(define (longer-than-n? s n)
  (> (string-length s) n))
=================================================================
============================Q2===================================
(@htdf largest)
(@signature Number Number Number -> Number)
;; produce the largest of three numbers
(check-expect (largest 3 2 1) 3)
(check-expect (largest 2 1 3) 3)
(check-expect (largest 2 3 1) 3)

(@template Number)
; (define (largest x y z) z) ;stub
solution:
(define (largest x y z)
  (cond [(and (> x y) (> x z)) x]
        [(> y z) y]
        [else z]))
=================================================================
============================Q3===================================
;;
;; Design a function that consumes an image, a width, and a height. The
;; function should determine whether the image fits inside of a rectangle
;; with the given width and height.  You must include all relevant recipe
;; elements and @tags.

solution:
(@htdf fits?)
(@signature Image Natural Natural -> Boolean)  ;Number would have been OK
;; produce true if image w, h are < given w, h
(check-expect (fits? (rect 10 20) 11 21) #t)
(check-expect (fits? (rect 10 20) 11 20) #f)
(check-expect (fits? (rect 20 30) 20 31) #f)
(check-expect (fits? (rect 30 20) 31 19) #f)
(check-expect (fits? (rect 10 20)  9 21) #f)

;(define (fits? img w h) false) ;stub

(@template Image)                              ;the number type is OK

(define (fits? img w h)
  (and (< (image-width img) w)
       (< (image-height img) h)))

=================================================================
============================Q4===================================
;; During the design of the following function, one step of the recipe was
;; completed incorrectly.  Please fix the function design below to make it
;; correct. Remember our hint that only one step of the recipe was completed
;; incorrectly.
;;
;; You may assume that a correct standard ListOfNumber data definition exists
;; in this program.
;;
(@htdd ListOfNumber)
(@htdf contains-negative?)
(@signature ListOfNumber -> Boolean)
;; produce true if lon contains at least one negative number, false otherwise

(check-expect (contains-negative? empty) false)
(check-expect (contains-negative? (cons -5 empty)) true)
(check-expect (contains-negative? (cons 6 (cons 3 empty))) false)
(check-expect (contains-negative? (cons 6 (cons -3 empty))) true)

;(define (contains-negative? lon) false)   ;stub

(@template-origin ListOfNumber)

(define (contains-negative? lon)
  (cond [(empty? lon) false]
        [else
         (if (negative? (first lon))
             true
             (fn-for-lon (rest lon)))]))

solution:
fn-for-lonc  -> contains-negative?
=================================================================
============================Q5===================================
(require spd/tags)
(require 2htdp/image)

;; Data Definitions
(@htdd Shoe)
(define-struct shoe (bc nm dn cst))
;; Shoe is (make-shoe String String String Number)
;; interp. a shoe with barcode (bc), name (nm),
;;         designer name (dn) and cost (cst)

(define S1 (make-shoe "W340591" "Air Jordan" "Nike" 158.99))
(define S2 (make-shoe "W246545" "Hustle" "Jimmy Choo" 1818.99))
(define S3 (make-shoe "Z568465" "Kicks" "Vince Camuto" 205.99))

#;
(define (fn-for-shoe s)
  (... (shoe-bc s)
       (shoe-nm s)
       (shoe-dn s)
       (shoe-cst s)))

;; Template rules used:
;; - compound: 4 fields

(@htdd ListOfShoe)
;; ListOfShoe is one of:
;; - empty
;; - (cons Shoe ListOfShoe)
;; interp. a list of shoes

(define LOS-MT empty)
(define LOS-3 (cons S1 (cons S2 (cons S3 empty))))

#;
(define (fn-for-los los)
  (cond [(empty? los) (...)]
        [else
         (... (fn-for-shoe (first los))
              (fn-for-los (rest los)))]))

;;~~~~~~~~~~~~~~~~~~Question~~~~~~~~~~~~~~~~~~
;;Design a program that takes an arbitrary number of shoes and
;;a price n, and removes all shoes that cost more than n.

;solution:
(@signature ListOfShoe Number -> ListOfShoe)
;; produce a list of shoes from los that cost <= n
(check-expect (get-shoes-below-or-equal empty 6.5) empty)
(check-expect (get-shoes-below-or-equal LOS-3 6556.21) LOS-3 )
(check-expect (get-shoes-below-or-equal LOS-3 1005.5) (cons S1 (cons S3 empty)))

;(define (get-shoes-below-or-equal los n) empty)

;template from ListOfShoe with additional parameter
(define (get-shoes-below-or-equal los n)
  (cond [(empty? los) empty]
        [else
         (if (below-or-equal? (first los) n)
             (cons (first los) (get-shoes-below-or-equal (rest los) n))
             (get-shoes-below-or-equal (rest los) n))]))

(@signature Shoe Number -> Boolean)
;; produce true if s is <= n
(check-expect (below-or-equal? S1 14.99) false)
(check-expect (below-or-equal? S1 158.99) true)
(check-expect (below-or-equal? S3 208.99) true)

;(define (below-or-equal? s n) true)

;template from Shoe with additional parameter
(define (below-or-equal? s n)
  (<= (shoe-cst s) n))
=================================================================

javaIsTheBest

========================htdd question============================
============================Q1===================================
In this problem you will be given small fragments of problem descriptions. Each fragment 
describes some information in a problem domain that must be represented using data in a 
program. In each case you need to choose the form of data that would be most appropriate to 
represent this information.

Mark your choice by circling the most appropriate form of data.

(A) A territory of Canada (Yukon, Northwest, or Nunavut)
[simple atomic]  [interval]   [enumeration]  [itemization] [compound] [arbitrary-sized]

(B) A pedometer program with the date and steps taken.
[simple atomic]  [interval]   [enumeration]   [itemization]  [compound] [arbitrary-sized]

(C) The number of tickets sold for the FIFA Women s World Cup 2015 games
 [simple atomic] [interval]   [enumeration]   [itemization]  [compound]  [arbitrary-sized]

(D)  The names of all people who have bought a plane ticket from Air Canada
[simple atomic]  [interval]   [enumeration]   [itemization]  [compound]   [arbitrary-sized]

solution:
(A) enumeration
(B) compound
(C) simple atomic
(D) arbitrary-sized
=================================================================
============================Q2===================================
Below we have provided partial data definitions that represent an academic grade.

We have provided the types comment, interpretation, and examples. Complete the
data definition by writing the template and the template rules used.

;; AcademicGrade is one of:
;; - "IEA"
;; - "WDR"
;; - "AMC"
;; - Natural [0, 100]
;; interp. the grade for a student which can be
;;         "IEA" is insufficient evidence available,
;;         "WDR" is withdrawl and "AMC" is academic misconduct
;;         the grade in percent

(define AG-IEA "IEA")
(define AG-WDR "WDR")
(define AG-AMC "AMC")
(define AG-100 100)
(define AG-56 56.7)
(define AG-0 0)

soulution:
;; AcademicGrade is one of:
;; - "IEA"
;; - "WDR"
;; - "AMC"
;; - Natural [0, 100]
;; interp. the grade for a student which can be
;;         "IEA" is insufficient evidence available,
;;         "WDR" is withdrawl and "AMC" is academic misconduct
;;         the grade in percent

(define AG-IEA "IEA")
(define AG-WDR "WDR")
(define AG-AMC "AMC")
(define AG-100 100)
(define AG-56 56.7)
(define AG-0 0)
=================================================================
============================Q3===================================
;;
;; Please write the template rules used tag and template for the following type
;; comment.  

;;
;; NO simplification is required, but the template must work correctly for all
;; data described by this

(define-struct apple (kind weight))
;; Foo is one of:
;;  - Number
;;  - "x"
;;  - "y"
;;  - (make-apple String Number)

solution:
(@dd-template-rules one-of
                    atomic-non-distinct
                    atomic-distinct
                    atomic-distinct
                    compound)

(define (fn-for-foo f)
  (cond [(number? f) (... f)]
        [(and (string? f) (string=? f "x")) (...)]
        [(and (string? f) (string=? f "y")) (...)] ;ok w/o guard
        [else
         (... (apple-kind f)
              (apple-weight f))]))
=================================================================
============================Q4===================================
;; Given the following type comment and structure definition write the
;; @dd-template-rules tag and the template for Cooo.
(@htdd Baaa)
;; Baaa is one of:
;; - "black"
;; - "red"
;; - "orange"
;; interp. the colors on planet X
;; <examples are redundant for enumerations>

(@dd-template-rules one-of            ; 3 cases
                    atomic-distinct   ; "black"
                    atomic-distinct   ; "red"
                    atomic-distinct)  ; "orange"

(define (fn-for-baaa b)
  (cond [(string=? b "black") (...)]
        [(string=? b "red") (...)]
        [(string=? b "orange") (...)]))
        

(@htdd Cooo)
(define-struct huuu (intensity vis? col))
;; Cooo is one of:
;; - "cyborg"
;; - (make-huuu Number Boolean Baaa)
;; - Natural


solution:
(@dd-template-rules one-of               ; 3 cases      

                    atomic-distinct      ; "cyborg"
                    compound             ; (make-huuu Number Boolean Baaa)
                    ref                  ; (huuu-col) is Baaa
                    atomic-non-distinct) ; Natural

(define (fn-for-cooo c)
  (cond [(string? c) (...)]
        [(huuu? c) (... (huuu-intensity c)
                        (huuu-vis? c)
                        (fn-for-baaa (huuu-col c)))]
        [else (... c)]))
=================================================================
============================Q5===================================
Given the following comments, draw the reference arrows and label each
arrow with one of R or SR.  

;;Circle is Integer

;;Rectangle is (make-rectangle Natural Natural)


;; Shape is one of:
;; - Circle
;; - Rectangle
;; interp. a shape, either a circle or a rectangle

;; ListOfShape is one of:
;; - empty
;; - (cons Shape ListOfShape)
=================================================================
============================Q6===================================
You are designing a system to manage a company's payroll and tax records.
So far, you've created a data definition to store a tax record for each employee.
Design a data definition for a list of tax records.

(define-struct tr (name emp-id ytd-salary))
;; TaxRecord is (make-tr String Natural Natural)
;; interp. an employee's tax record with their name, employee id,
;;         and their year-to-date salary
(define TR1 (make-tr "Qingwei Zhang" 1273 22000))
(define TR2 (make-tr "Dana Jia" 8760 39221))
#;
(define (fn-for-tax-record tr)
  (... (tr-name tr)
       (tr-emp-id tr)
       (tr-salary tr)))

;; Template rules used:
;; - compound: 3 fields

solution:
;; ListOfTaxRecord is one of:
;; - empty
;; - (cons TaxRecord ListOfTaxRecord)
;; interp. a list of tax records
(define LOTR0 empty)
(define LOTR1 (cons TR1 (cons TR2 empty)))
#;
(define (fn-for-lotr lotr)
  (cond [(empty? lotr) (...)]
        [else
         (... (fn-for-tax-record (first lotr))
              (fn-for-lotr (rest lotr)))]))

;; Template rules used:
;; - one of: 2 cases
;; - atomic distinct: empty
;; - compound: (cons TaxRecord ListOfTaxRecord)
;; - reference: (first lotr) is TaxRecord
;; - self-reference: (rest lotr) is ListOfTaxRecord
=================================================================
============================Q7===================================
In your payroll system, you need a function that updates all the tax records on each payday.
Design a function that updates the records when employees are paid. Your function must
take a list of tax records and a salary and produce a new list in which each tax record's
year-to-date salary has been increased by the given salary.

solution:
;; ListOfTaxRecord Natural -> ListOfTaxRecord
;; adds s to each record in lotr
(check-expect (update-salaries empty 1000) empty)
(check-expect (update-salaries (cons (make-tr "Qingwei Zhang" 1273 22000)
                                     (cons (make-tr "Dana Jia" 8760 39221) empty))
                               1200)
              (cons (make-tr "Qingwei Zhang" 1273 (+ 1200 22000))
                    (cons (make-tr "Dana Jia" 8760 (+ 1200 39221)) empty))) 

;(define (update-salaries lotr s) lotr)

;; Template from ListOfTaxRecord with additional atomic parameter
(define (update-salaries lotr s)
  (cond [(empty? lotr) empty]
        [else
         (cons (update-salary (first lotr) s)
               (update-salaries (rest lotr) s))]))


;; TaxRecord Natural -> TaxRecord
;; adds s to year-to-date salary of tr
(check-expect (update-salary (make-tr "Qingwei Zhang" 1273 22000) 700)
              (make-tr "Qingwei Zhang" 1273 (+ 700 22000)))
(check-expect (update-salary (make-tr "Qingwei Zhang" 1273 22000) 500)
              (make-tr "Qingwei Zhang" 1273 (+ 500 22000)))
;(define (update-salary tr s) tr)

;; Template from TaxRecord with additional atomic parameter 
(define (update-salary tr s)
  (make-tr (tr-name tr)
           (tr-emp-id tr)
           (+ (tr-ytd-salary tr) s)))
=================================================================

javaIsTheBest

======================bi-bang + itemization=====================================
Program Description: This program displays a single traffic light. When the program
starts the light is green (on). When the spacebar is pressed, the traffic light colour
changes (from green to yellow, yellow to red, red to green, etc.) When the mouse is
clicked the light turns off. Once the light is off, it cannot come back on again.

;; ==========
;; Constants:

(define WIDTH 120)
(define HEIGHT 100)

(define LIGHT-RADIUS 20)

(define MTS (empty-scene WIDTH HEIGHT))

;; LightColour is one of:
;; - "red"
;; - "yellow"
;; - "green"
;; interp. the colour of a traffic light
;; <examples are redundant for enumerations>

(define (fn-for-light-colour lc)
  (cond [(string=? "red" lc) (...)]
        [(string=? "yellow" lc) (...)]
        [(string=? "green" lc) (...)]))

;; Template rules used:
;; - one of: 3 cases
;; - atomic distinct: "red"
;; - atomic distinct: "yellow"
;; - atomic distinct: "green"



;; TrafficLight is one of:
;; - false
;; - LightColour
;; interp. a traffic light: false means the light is off, otherwise it is the given colour
(define TL1 false)
(define TL2 "red")
(define TL3 "green")

(define (fn-for-traffic-light tl)
  (cond [(false? tl) (...)]
        [else
         (... (fn-for-light-colour tl))]))

;; Template rules used:
;; - one of: 2 cases
;; - atomic distinct: false
;; - reference: LightColour

;; =================
;; Functions:

;; TrafficLight -> TrafficLight
;; start the world with (main "green")
;; no tests for main functions
(define (main tl)
  (big-bang tl                        ; TrafficLight
            (to-draw   render-tl)     ; TrafficLight -> Image
            (on-mouse  handle-mouse)  ; TrafficLight Integer Integer MouseEvent 
                                      ; -> TrafficLight
            (on-key    handle-key)))  ; TrafficLight KeyEvent -> TrafficLight

problem 1: draw arrows
problem 2: Complete the design of the render-tl function based on the wish-list entry below.
You must write examples, a note stating where you took the template from
and a complete function definition. You do not need to repeat the signature,
purpose and stub.

solution:

;; TrafficLight -> Image
;; place rendering of the traffic light in the middle of MTS
(check-expect (render-tl "red") (overlay (circle LIGHT-RADIUS "solid" "red")
                                         MTS))
(check-expect (render-tl false) (overlay (text "light is off" 24 "black")
                                         MTS))


;; Took template from TrafficLight
(define (render-tl tl)
  (cond [(false? tl)(overlay (text "light is off" 24 "black")
                             MTS)]
        [else
         (overlay (render-light-colour tl)
                  MTS)]))

;; LightColour -> Image
;; render an image dislaying the light colour
(check-expect (render-light-colour "red") (circle LIGHT-RADIUS "solid" "red"))
(check-expect (render-light-colour "green") (circle LIGHT-RADIUS "solid" "green"))
(check-expect (render-light-colour "yellow") (circle LIGHT-RADIUS "solid" "yellow"))

;; Took template from LightColour
(define (render-light-colour s)
  (cond [(string=? "red" s) (circle LIGHT-RADIUS "solid" "red")]
        [(string=? "yellow" s) (circle LIGHT-RADIUS "solid" "yellow")]
        [(string=? "green" s) (circle LIGHT-RADIUS "solid" "green")]))

problem 3: Complete the design of the handle-mouse function based on the wish-list entry below.
You must write examples, a note stating where you took the template from
and a complete function definition. You do not need to repeat the signature, purpose
and stub.
solution:

;; TrafficLight Integer Integer MouseEvent -> TrafficLight
;; turns the light off when the mouse is clicked
(check-expect (handle-mouse "red" 93 23 "drag") "red")
(check-expect (handle-mouse "green" 22 11 "button-down") false)
;(define (handle-mouse tl x y me) tl) 

;; Took template from MouseEvent

(define (handle-mouse tl x y me)
  (cond [(mouse=? me "button-down") false]
        [else
         tl]))



;  YOU DO NOT NEED TO COMPLETE THE HANDLE-KEY FUNCTION DESIGN. THE WISH-LIST ENTRY IS PROVIDED 
; FOR COMPLETENESS OF THE PROGRAM ONLY.


;; TrafficLight KeyEvent -> TrafficLight
;; when the spacebar is pressed, if the light is on it changes colour (red > green > yellow > red, etc.)
;; !!!
(define (handle-key tl ke) tl)

javaIsTheBest

======================bi-bang + compound=====================================
The world begins with a stationary star in the middle of the screen.
When one of these arrow keys is pressed the star moves by one speed increment, as follows:

right with the right arrow key
up with the up arrow key

If you press an arrow key many times, it will reach the edge of the screen,
at which point it should appear at the other edge of the screen.

We have provided you with a complete domain analysis, constants, and data definition.
You must complete the design of the world program by following the
rest of the How to Design Worlds recipe.

(require 2htdp/image)
(require 2htdp/universe)


;; =================
;; Constants:

(define WD 800)
(define HT 400)

(define CTR-X (/ WD 2))
(define CTR-Y (/ HT 2))

(define MTS (empty-scene WD HT))

(define STAR (star 20 "solid" "black"))

(define SPD 3)


;; =================
;; Data Definitions:


(define-struct sstar (x y))
;; SStar is (make-sstar Natural[0,WD] Natural[0,HT])
;; interp. a SStar that is centered at position (x, y) in pixels
(define S-CTR (make-sstar CTR-X CTR-Y))
(define S-TOP (make-sstar CTR-X 0))
(define S-BOT (make-sstar CTR-X HT))
(define S-LFT (make-sstar 0 CTR-Y))
(define S-RGT (make-sstar WD CTR-Y))

#;
(define (fn-for-sstar s)
  (... (sstar-x s)
       (sstar-y s)))

;; Template rules used:
;; - compound: 2 fields

solution:

;; SStar -> SStar
;; start the world with (main S-CTR)
;; no tests for main functions
(define (main s)
  (big-bang s                      ; SStar
            (to-draw draw-sstar)   ; SStar -> Image
            (on-key  handle-key))) ; SStar KeyEvent -> SStar
            

 ;; SStar -> Image
;; render STAR onto MTS at s screen coordinates
(check-expect (draw-sstar S-CTR) (place-image STAR CTR-X CTR-Y MTS))
(check-expect (draw-sstar S-TOP) (place-image STAR CTR-X 0 MTS)) 
(check-expect (draw-sstar S-BOT) (place-image STAR CTR-X HT MTS))
(check-expect (draw-sstar S-LFT) (place-image STAR 0 CTR-Y MTS))
(check-expect (draw-sstar S-RGT) (place-image STAR WD CTR-Y MTS))

;(define (draw-sstar s) empty-image) ;stub

; template from SStar
(define (draw-sstar s)
  (place-image STAR (sstar-x s) (sstar-y s) MTS))



;; SStar KeyEvent -> SStar
;; produce SStar moved SPD in the direction corresponding to the arrow pressed
(check-expect (handle-key S-CTR "up") 
              (make-sstar CTR-X (- CTR-Y SPD)))
(check-expect (handle-key S-TOP "up")
              (make-sstar CTR-X HT))
(check-expect (handle-key S-BOT "up")
              (make-sstar CTR-X (- HT SPD)))
(check-expect (handle-key S-CTR "right")
              (make-sstar (+ CTR-X SPD) CTR-Y))
(check-expect (handle-key S-LFT "right")
              (make-sstar (+ 0 SPD) CTR-Y))
(check-expect (handle-key S-RGT "right")
              (make-sstar 0 CTR-Y))
(check-expect (handle-key S-CTR "m")
              S-CTR)

;(define (handle-key s ke) s) ;stub

; Template from KeyEvent as large enumeration with additional parameter
(define (handle-key s ke)
  (cond [(key=? ke "right") (if (> (+ (sstar-x s) SPD) WD)
                                (make-sstar 0 (sstar-y s))
                                (make-sstar (+ (sstar-x s) SPD) (sstar-y s)))]
        [(key=? ke "up")    (if (< (- (sstar-y s) SPD) 0)
                                (make-sstar (sstar-x s) HT) 
                                (make-sstar (sstar-x s) (- (sstar-y s) SPD)))]
        [else s]))

javaIsTheBest

======================bi-bang + list + ref=====================================
In this problem we are giving you a written description of a world program and a
complete domain analysis for the world program. YOU WILL ONLY DESIGN THE DATA
DEFINITIONS IN THIS WORLD. You should assume that all previous steps are completed,
and should not continue to subsequent steps. Detailed instructions for what your solution
must include are at the bottom of this comment box.

Program Description: When the mouse is clicked, a truck appears at that position on the
screen. The truck moves towards the right and off the screen. Each time you click the
mouse, a new truck is created at that position. When the space (" ") key is pressed,
all the trucks stop moving. Pressing the space key again will make all the trucks move again.

Design appropriate data definitions to represent the changing information of
this program. Use one or more data definitions as you see fit. You may use
constants that are included in the domain analysis.

solution:

(define-struct truck (x y moving?))
;; Truck is (make-truck Integer Integer Boolean)
;; interp. a truck with x, y position in screen coordinates
;;         and whether it is currently moving
(define T0 (make-truck 0 0 true))
(define T1 (make-truck 25 30 false))

#;
(define (fn-for-truck t)
  (... (truck-x t)
       (truck-y t)
       (truck-moving? t)))

;; Template Rules Used:
;; - compound: 3 fields


;; ListOfTruck is one of:
;; - empty
;; - (cons Truck ListOfTruck)
;; interp. a list of trucks
(define LOT0 empty)
(define LOT1 (cons T0 (cons T1 empty)))

#;
(define (fn-for-lot lot)
  (cond [(empty? lot) ...]
        [else
         (... (fn-for-truck (first lot))
              (fn-for-lot (rest lot)))]))

;; Template Rules Used:
;; - one of: 2 cases
;; - atomic distinct: empty
;; - compound: 2 fields
;; - reference: (first lot) is Truck
;; - self-reference: (rest lot) is ListOfTruck

javaIsTheBest

======================bi-bang + mix(atomic + compound )=====================================
Program Description: This program simulates an elevator control. It has two buttons
that you can use to call the elevator. One calls the elevator to go up and one calls
the elevator to go down. The buttons light up when the corresponding elevators are
called. The light goes off when the call is cancelled. You can call the elevator
to go up by pressing the “u” key. If you press the “u” key again, it cancels the
call. Similarly, the “d” key is used to call the elevator to go down. If you press
“d” again, the call is cancelled.

;;=======================================
;; Data Definitions

;; UpButton is Boolean
;; interp. true means button is lit

(define UB0 false)
(define UB1 true)
#;
(define (fn-for-up-button b)
  (... b))
;; Template rules used:
;; - atomic non-distict: Boolean


;; DownButton is Boolean
;; interp. true means button is lit

(define DB0 false)
(define DB1 true)
#;
(define (fn-for-down-button b)
  (... b))
;; Template rules used:
;; - atomic non-distict: Boolean


(define-struct control (up-button down-button))
;; Control is (make-control UpButton DownButton)
;; interp. an elevator control on a particular floor. It controls calling the elevator
;;         to go up or down (or both)
(define C00 (make-control false false))
(define C01 (make-control false true))
(define C10 (make-control true  false))
(define C11 (make-control true  true))

#;
(define (fn-for-control c)
  (... (fn-for-up-button (control-up-button c))
       (fn-for-down-button (control-down-button c))))

;; Template rules used:
;; - compound: 2 fields
;; - reference (control-up-button c) is UpButton
;; - reference (control-down-button c) is DownButton


;; =========
;; Functions

;; Control -> Control
;; start the world with (main (make-control false false))
;; no tests for main functions
(define (main c)
  (big-bang c                           ; Control
            (to-draw   render-control)  ; Control -> Image
            (on-key    handle-key)))    ; Control KeyEvent -> Control

Problem 1: draw arrows
Problem 2:
Complete the design of the render-control function based on the wish-list entry below.
You must write check-expects, a note stating where you took the template from
and a complete function definition. You do not need to repeat the signature,
purpose and stub. You may use the image constants defined above.

solution:

;; Control -> Image
;; render the elevator control lights
(check-expect (render-control (make-control true true)) 
              (overlay (above UP-LIT DOWN-LIT)
                       MTS))
(check-expect (render-control (make-control true false))
              (overlay (above UP-LIT DOWN-OFF)
                       MTS))
;(define (render-control c) empty-image)

; <template copied from Control>

(define (render-control c)
  (overlay (above (render-up-button (control-up-button c))
                  (render-down-button (control-down-button c)))
           MTS))

;; UpButton -> Image
;; produce a an image for the up button
(check-expect (render-up-button true) UP-LIT)
(check-expect (render-up-button false) UP-OFF)

;(define (render-up-button b) empty-image)

; <template copied from UpButton>

(define (render-up-button b)
  (if b
      UP-LIT
      UP-OFF))

;; DownButton -> Image
;; produce a an image for the down button
(check-expect (render-down-button true) DOWN-LIT)
(check-expect (render-down-button false) DOWN-OFF)

;(define (render-down-button b) empty-image)

; <template copied from DownButton>

(define (render-down-button b)
  (if b
      DOWN-LIT
      DOWN-OFF))